Joindre un ordinateur au domaine


Cet exemple de script avec son code permet de joindre un ordinateur(pc windows) au domaine du réseau d'entreprise.

Il vous faudra modifier le programme pour que l'ordinateur soit intégré dans la bonne OU. Vous devrez aussi indiquer les paramètres du nom de domaine.

Par sécurité et seulement quand vous executerez le script, il vous sera demandé de saisir au clavier un compte opérateur ayant les droits pour la jonction au domaine ainsi qu'un mot de passe.
Cette précaution évite de laisser un mot de passe dans un fichier qui pourrait être oublié sur une machine ou une clé usb.

Code du script VBS


' *************************************************************************************
' Joindre un ordinateur au domaine de votre réseau
' *************************************************************************************

Option Explicit

Dim strDomain, strUser, strPassword, strOU
Dim objNetwork, strComputer, objComputer, ReturnErrorValue

Const JOIN_DOMAIN = 1
Const ACCT_CREATE = 2
Const ACCT_DELETE = 4
Const WIN9X_UPGRADE = 16
Const DOMAIN_JOIN_IF_JOINED = 32
Const JOIN_UNSECURE = 64
Const MACHINE_PASSWORD_PASSED = 128
Const DEFERRED_SPN_SET = 256
Const INSTALL_INVOCATION = 262144

'strDomain = InputBox("Entrer un nom de domaine")
'strDomain = "NomDomaine.Site.Local"
strDomain = "NomDomaine.Site.Local"
strUser = InputBox("Entrer un compte opérateur", "Joindre un ordinateur au domaine") 
strPassword = InputBox("Entrer un mot de passe", "Joindre un ordinateur au domaine")

' Indiquer l'OU où sera créé le compte ordinateur **************************************
' strOU = "CN=Computers,DC=NomDomaine,DC=Site,DC=Local"
strOU = "OU=B101,OU=Bureaux,OU=Ordinateurs,DC=NomDomaine,DC=Site,DC=Local"

' Récupération du nom de l'ordinateur local ********************************************
Set objNetwork = CreateObject("WScript.Network")
strComputer = objNetwork.ComputerName

Set objComputer = GetObject("winmgmts:" _
& "{impersonationLevel=Impersonate,authenticationLevel=Pkt}!\\" & _
strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & _
strComputer & "'")


' Codes d'erreurs à afficher ***********************************************************
ReturnErrorValue = objComputer.JoinDomainOrWorkGroup(strDomain, _
strPassword, strDomain & "\" & strUser, strOU, _
JOIN_DOMAIN + ACCT_CREATE)

Wscript.Echo "Code erreur = " & CStr(ReturnErrorValue)

Select Case ReturnErrorValue

Case 0
Wscript.Echo "L'ordinateur " & strComputer & " est joint au domaine " & strDomain & " avec succès!"
Case 5
Wscript.Echo "L'accés est refusé"
Case 87
Wscript.Echo "Le paramètre est incorrect"
Case 110
Wscript.Echo "Le système ne peut ouvrir l'objet spécifié"
Case 234 
Wscript.Echo "Données erronées"
Case 1323
Wscript.Echo "Le mot de passe n'est pas correct"
Case 1326
Wscript.Echo "Erreur de connexion : vérifier le compte et le mot de passe"
Case 1355
Wscript.Echo "Les spécifications du domaine n'existent pas ou il ne peut être contacté"
Case 2224
Wscript.Echo "Le compte existe déjà"
Case 2691
Wscript.Echo "L'ordinateur est déjà joint au domaine"
Case 2692
Wscript.Echo "L'ordinateur ne s'est pas joint au domaine"
Case Else
Wscript.Echo "Erreur Inconnue"
End Select
' **************************************************************************************




Saisir le nom du compte opérateur ou administrateur ayant les droits de création.

VBScripts - joindre un ordinateur au domaine du réseau - AD - LDAP - ordinateur pc - codes et exemples

Indiquer le mot de passe.

VBScripts - joindre un ordinateur au domaine du réseau - AD - LDAP - ordinateur pc - codes et exemples

Code erreur à 0 pour une exécution avec succès.

VBScripts - joindre un ordinateur au domaine du réseau - AD - LDAP - ordinateur pc - codes et exemples

Le contrôle et l'affichage du résultat ou d'un code erreur vous permettra de vérifier l'execution du script.

VBScripts - joindre un ordinateur au domaine du réseau - AD - LDAP - ordinateur pc - codes et exemples


Liste des codes d'erreurs Windows (Windows System Error Codes): Lien vers la liste complète.



Lire la suite »






0239039